MacWorld 1997 August/Macworld (1997-08).dmg/Shareware World/Info/For Developers/InstallerMaker™ 4.0 Installer/Customizing InstallerMaker/Scripting InstallerMaker/Text Files/Log Archive to BBEdit

Text File | 1996-02-01 | 14KB | 507 lines

(*

Archive logging script, version 2

A demo script for InstallerMaker 3.0's new scripting features.

We don't guarantee that this script is fit for any purpose, but you can
learn quite a lot about AppleScript in general and using AppleScript with
InstallerMaker by reading this.

This script assumes that it's working on the frontmost archive, and doesn't
have the necessary error checking to make sure that the user hasn't messed
with the order of the archive windows.  A more general script than this one
would probably check for that possibility.

12/7/95, RMT

*)

-- For diagnostic purposes, this version does logging to BBEdit
on ExistsBBWin()
    set itExists to true
    tell application "BBEdit 3.5"
        try
            copy (name of window 1) to theNULL
        on error err
            set itExists to false
        end try
    end tell

    return itExists
end ExistsBBWin

on SaveThisFile(logPath)
    tell application "BBEdit 3.5" to save window 1 to file logPath
end SaveThisFile

on LogText(someText)
    --Small utility for printing lines to the Scriptable Text Editor
    set hasWindow to false
    if ExistsBBWin() then
        set hasWindow to true
    end if

    tell application "BBEdit 3.5"
        --activate
        if not hasWindow then ¬
            create window
        tell window 1
            Insert Text (someText as string) & return
        end tell
    end tell
end LogText


on PointString(pointList)
    return "{" & item 1 of pointList & ¬
        "," & item 2 of pointList & "}"
end PointString

on FormatListOfString(strList)
    copy (count of strList) to cnt

    copy "{" to str

    if cnt > 0 then

        if cnt > 1 then
            repeat with i from 1 to cnt - 1
                copy str & "\"" & item i of strList & "\"" & "," to str
            end repeat
        end if
        copy str & "\"" & item cnt of strList & "\"" & "}" to str -- last item, so no comma

    else
        copy "{}" to str
    end if

    return str
end FormatListOfString

on PrintClassItem(prefix, itemRef)

    tell application "StuffIt Installer™ 3.0"
        copy name of itemRef to itsName
        copy type of itemRef to itsType
        copy (creation date of itemRef) to createDate
        copy (modification date of itemRef) to modDate

        tell me
            copy createDate as string to itsCreateDate
            copy modDate as string to itsModDate
        end tell

        copy size of itemRef to itsDiskSize
        copy compressed size of itemRef to itsCompressedSize
        copy label of itemRef to itsFinderLabel
        copy compressed of itemRef to isCompressed
        copy encrypted of itemRef to isEncrypted
        --copy top level of itemRef to isTopLevel
        copy user tag of itemRef to itsUserTag
        copy position of itemRef to itsPositionPoint
        --copy parent  of itemRef to itsParRef
        copy item number of itemRef to itsIndex
    end tell

    tell me
        LogText(prefix)
        LogText(prefix & "#" & itsIndex)
        LogText(prefix & "Name: \"" & itsName)
        LogText(prefix & "==============================")
        LogText(prefix & "Properties from Class Item")
        LogText(prefix & "==============================")
        LogText(prefix & "Type: " & itsType)
        LogText(prefix & "Size on disk: " & itsDiskSize)
        LogText(prefix & "Size in archive: " & itsCompressedSize)

        if isCompressed then
            set str to "Item is compressed"
        else
            set str to "Item is not compressed"
        end if

        LogText(prefix & str)

        if isEncrypted then
            set str to "Item is encrypted"
        else
            set str to "Item is not encrypted"
        end if

        LogText(prefix & str)


        LogText(prefix & "Item was Created on: " & itsCreateDate)
        LogText(prefix & "Item was Last Modified on: " & itsModDate)

        copy PointString(itsPositionPoint) to ptStr
        LogText(prefix & "Position in Finder Window: " & ptStr)

        LogText(prefix & "User Tag: " & itsUserTag)
    end tell

end PrintClassItem


on PrintClassTopLevel(prefix, itemRef)
    --I assume that the caller has actually tested the item, and is sure it's top level material
    tell application "StuffIt Installer™ 3.0"
        copy package definition of itemRef to packList -- note this is new in 3.0b1
        copy version condition of itemRef to itsVersCondit
        if itsVersCondit is "range" then
            copy version range condition of itemRef to itsVersRange
        else
            copy {} to itsVersRange
        end if

        copy existing file condition of itemRef to itsExistsCondit
        copy Gestalt condition of itemRef to itsGestaltRec
        copy system condition of itemRef to itsSysCondit
        copy display condition of itemRef to itsDisplayCondit
        copy processor condition of itemRef to itsProcCondit
        copy custom condition of itemRef to itsCustCondit
    end tell

    copy FormatListOfString(packList) to packStr

    LogText(prefix & "==============================")
    LogText(prefix & "Top Level Settings")
    LogText(prefix & "==============================")
    LogText(prefix & "Assigned to Packages: " & packStr)
    LogText(prefix & "File Exists Test: " & itsExistsCondit)
    LogText(prefix & "Version Test Type: " & itsVersCondit)
    LogText(prefix & "System Class Test: " & itsSysCondit)
    LogText(prefix & "Display Type Test: " & itsDisplayCondit)
    LogText(prefix & "Processor Type Test: " & itsProcCondit)
    LogText(prefix & "Custom Condition Bits: " & itsCustCondit)
    --LogText(prefix & "xxx: " & xx )

    --return packList

end PrintClassTopLevel


on NewTLItemBoarder()
    LogText("============================================================")
end NewTLItemBoarder

on LogGestaltCondition(prefix, theGestalt)
    --This examine a gestalt record and prints it out in a human readable form
    tell application "StuffIt Installer™ 3.0"
        set selectorStr to ""
        set conditStr to ""

        -- The only safe way to test a record for entries
        -- is to use try handlers.

        -- Find out what we've selected:
        try
            copy "Selector Exists: " & ¬
                given selector exists and condition met of theGestalt to selectorStr
        on error
            try
                copy "Selector Does Not Exist: " & ¬
                    given selector does not exist of theGestalt to selectorStr
            on error
                try
                    copy "Selector Does Not Exist (w/Condition): " & ¬
                        given selector does not exist or condition of theGestalt to selectorStr
                on error
                    copy "<No Selector>" to selectorStr
                end try
            end try
        end try


        -- Check for conditions
        try
            copy "Data = " & ¬
                data equal of theGestalt to conditStr
        on error
            try
                copy "Data ≠ " & ¬
                    data not equal of theGestalt to conditStr
            on error
                try
                    copy "Bit Mask (Set): " & ¬
                        bits set of theGestalt to conditStr
                on error
                    try
                        copy "Bit Mask (Not Set): " & ¬
                            bits clear of theGestalt to conditStr
                    on error
                        try
                            copy "Data ≥ " & ¬
                                data greater than or equal of theGestalt to conditStr
                        on error
                            try
                                copy "Data ≤ " & ¬
                                    data less than or equal of theGestalt to conditStr
                            on error
                                copy "<No Condition>" to conditStr
                            end try
                        end try
                    end try
                end try
            end try
        end try

    end tell

    LogText(prefix & "Gestalt Selector and Condition Tests:")
    LogText(prefix & selectorStr)
    LogText(prefix & conditStr)
    return {selectorStr, conditStr}

end LogGestaltCondition


on PrintArchiveInfo(arcRef)
    NewTLItemBoarder()
    LogText("")

    --Now get some info about the archive
    tell application "StuffIt Installer™ 3.0"
        copy archive name of arcRef to arcName
        copy pathname of arcRef to arcPath
        copy language of arcRef to arcLang
        copy linked resources of arcRef to linkedRes
        copy version to appVers
    end tell

    LogText("Archive: " & arcName)
    LogText("Type: InstallerMaker " & appVers & " archive")
    LogText("Location on Disk: " & arcPath)
    LogText("Prepared in Language: " & arcLang)
    LogText("Using Included Resource File: " & linkedRes)
    LogText("")
    NewTLItemBoarder()
end PrintArchiveInfo

on LogMinimumSystem(prefix, minSysRec)
    --Packages may have an empty record if min sys feature not used
    if minSysRec is {} then
        LogText("prefix & [No Minimum System Conditions Defined]")
        return
    end if

    --Otherwise everything is defined, and is true or false

    tell application "StuffIt Installer™ 3.0"
        --We get back a version integer.  We'll parse it.
        copy minimum System Version of minSysRec to sysInt
        copy ((sysInt) div 256) to majorRev
        copy (sysInt - majorRev * 256) div 16 to subRev
        copy (sysInt - majorRev * 256 - subRev * 16) to fixRev

        copy (majorRev as string) & "." & subRev & "." & fixRev to verStr
        tell me to LogText(prefix & "Minimum System Version: " & verStr)

        copy minimum RAM of minSysRec to minRAM
        tell me to LogText(prefix & "Physical RAM required: " & minRAM & "K")


        (*

        -- This section is disabled, due to a terminology conflict on
        -- "dont allow override".

        if dont allow override of warning of minSysRec then
            tell me to LogText ("Require These Conditions for Installation:")
        else
            tell me to LogText ("Warn User If These Conditions Not Met:")
        end if
    *)
        tell me to LogText(prefix & "Check for Conditions:")

        if requires ColorQuickDraw of minSysRec then
            tell me to LogText(prefix & "ColorQuickDraw")
        end if

        set someConditSet to false

        if requires ColorQuickDraw32 of minSysRec then
            tell me to LogText(prefix & "ColorQuickDraw32")
            set someConditSet to true
        end if

        if requires CPU020 of minSysRec then
            tell me to LogText(prefix & "68020 Equivalent or Better")
            set someConditSet to true
        end if

        if requires MMU of minSysRec then
            tell me to LogText(prefix & "MMU")
            set someConditSet to true
        end if

        if requires FPU of minSysRec then
            tell me to LogText(prefix & "FPU")
            set someConditSet to true
        end if


        if requires QuickTime of minSysRec then
            tell me to LogText(prefix & "QuickTime")
            set someConditSet to true
        end if


        if requires PowerManager of minSysRec then
            tell me to LogText(prefix & "PowerManager")
            set someConditSet to true
        end if


        if requires PowerTalk of minSysRec then
            tell me to LogText(prefix & "PowerTalk")
            set someConditSet to true
        end if


        if requires PowerPC of minSysRec then
            tell me to LogText(prefix & "PowerPC")
            set someConditSet to true
        end if


        if requires Color Capable of minSysRec then
            tell me to LogText(prefix & "Color Capable Monitor")
            set someConditSet to true
        end if

        copy Gestalt condition of minSysRec to itsGestalt

        if itsGestalt is not {} then
            tell me to LogGestaltCondition(prefix, itsGestalt)
            set someConditSet to true
        end if

        if not someConditSet then
            tell me to LogText(prefix & "[No Conditions Specified]")
        end if

    end tell

end LogMinimumSystem

on PrintGlobalInfo(arcRef)
    LogText("")
    LogText("**Global Data For This Archive**")
    LogText("Minimum Conditions for Installation:")

    tell application "StuffIt Installer™ 3.0"
        copy minimum system of arcRef to theMinSysRec
    end tell
    LogMinimumSystem("> ", theMinSysRec)

end PrintGlobalInfo

on PrintPackageInfo(arcRef)
    LogText("[Package info is broken in 3.0a3]")
end PrintPackageInfo


on ProcessSubFolder(prefix, folderRef)
    tell me
        LogText(prefix, "[We'd print subitems here, and recurse if needed]")
    end tell

    set myPrefix to prefix & "|---"

    tell application "StuffIt Installer™ 3.0"

        set current folder of archive 1 to folderRef -- Deal with a bug in 3.0b1 that confuses
        ----------------------------------------------- count and item number for a closed folder

        copy (count of items in folderRef) to theCount

        if theCount is 0 then
            tell me to LogText("[No items in archive]")
        else
            tell me to LogText(myPrefix & theCount & " items in this folder.")
            repeat with i from 1 to theCount
                tell application "StuffIt Installer™ 3.0"
                    copy (a reference to item i of folderRef) to thisItem
                    copy type of thisItem to itsType
                end tell

                tell me
                    PrintClassItem(myPrefix, thisItem)

                    if itsType is "folder" then
                        beep 2
                        ProcessSubFolder(myPrefix, thisItem)
                        tell application "StuffIt Installer™ 3.0"
                            set current folder of archive 1 to folderRef
                        end tell

                    else
                        LogText(myPrefix & "Type is not folder, but \"" & itsType & "\"")
                    end if
                end tell

            end repeat
        end if
    end tell


end ProcessSubFolder

on ProcessTopLevel(arcRef)
    --This one starts the printout of archive item information.
    tell application "StuffIt Installer™ 3.0"
        if class of arcRef is not archive then
            error "Don't call this handler for non-archives!"
        end if

        set current folder of arcRef to arcRef -- there's a bug in get item number!

        copy (count of items in arcRef) to theCount

        if theCount is 0 then
            tell me to LogText("[No items in archive]")
        else
            tell me to LogText(theCount & " items at top level.")

            repeat with i from 1 to theCount
                copy (a reference to top level item i of arcRef) to thisItem
                copy type of thisItem to itsType
                tell me
                    PrintClassItem("", thisItem)
                    PrintClassTopLevel("", thisItem)

                    if itsType is "folder" then
                        beep 2
                        tell application "StuffIt Installer™ 3.0"
                            copy (a reference to folder i of arcRef) to aFldrRef
                        end tell


                        ProcessSubFolder("", aFldrRef)

                        tell application "StuffIt Installer™ 3.0"
                            set current folder of arcRef to arcRef
                        end tell
                    else
                        LogText("Type is not folder, but \"" & itsType & "\"")
                    end if
                end tell
            end repeat
        end if
    end tell

end ProcessTopLevel
--Start execution here....

tell application "StuffIt Installer™ 3.0"
    copy (a reference to archive 1) to arcRef
    tell me to PrintArchiveInfo(arcRef)
end tell

PrintGlobalInfo(arcRef)
LogText("")
PrintPackageInfo(arcRef)
LogText("")
--ProcessTopLevel(arcRef)